19 Labor Supply and Welfare Participation with Time Limits

In 1996 the Personal Responsibility and Work Opportunity Reconciliation Act (PRWORA) replaced the main cash welfare program in the United States, Aid to Families with Dependent Children (AFDC), with Temporary Assistance for Needy Families (TANF). Among the many changes introduced by the reform, perhaps the most novel was a lifetime limit on receipt of federally funded benefits: 60 months in total, with states free to impose shorter limits.

Time limits are a natural application for dynamic discrete choice. Under AFDC, a family’s decision to participate in welfare this year had (to a first approximation) no effect on its options next year. Under a time limit, every period of participation uses up a scarce resource. A forward-looking family should therefore recognize that receiving benefits today has an option value cost: it reduces the benefits that will be available if things go badly in the future. This leads to a sharp prediction, emphasized by Grogger (2002) and Grogger and Michalopoulos (2003): time limits should reduce welfare use before they bind, as families “bank” their eligibility. Moreover, the incentive to bank should be strongest for families who have the longest time left before they would lose eligibility anyway. Since eligibility for TANF ends when the youngest child turns 18, this means that the effect should be largest for families with young children. Grogger and Michalopoulos (2003) find evidence for exactly this pattern in the Florida Family Transition Program experiment.

The prediction is a statement about behavior rather than about the mechanical effect of removing families from the rolls once they hit the limit. Distinguishing these two channels is important for policy, and it requires a model. In this chapter we develop a stylized model of labor supply and program participation in the spirit of the much richer models of Swann (2005), Fang and Keane (2004), Keane and Wolpin (2010), and Chan (2013). We use it to:

Show how a time limit creates an endogenous, payoff-relevant state variable (cumulative program use) and how this generates anticipation effects.
Estimate the model by nested fixed point.
Decompose the effect of a time limit into mechanical and behavioral components, and see why a simple before-after comparison can be misleading about either.

Relative to the entry model, this model has a finite horizon, a richer choice set, and two endogenous state variables. It also illustrates an important practical point: in many labor applications, some objects that matter for decisions (here, wages) are observed in the data and can be estimated outside of the dynamic model.

19.1 The Model

Time is discrete, and we will think of a period as a year. A family (we’ll call the decision-maker “she” for brevity, since the overwhelming majority of adult welfare recipients are single mothers) is potentially eligible for welfare for $T$ periods, which we can think of as the time until her youngest child reaches the age at which eligibility ends.

Choices. In each period she chooses whether to work ($H\in\{0,1\}$) and whether to participate in the welfare program ($P\in\{0,1\}$). We index the four combinations by $j\in\{1,2,3,4\}$: \[ (H_{1},P_{1}) = (0,0),\quad (H_{2},P_{2}) = (1,0),\quad (H_{3},P_{3}) = (0,1),\quad (H_{4},P_{4}) = (1,1). \]

Wages and human capital. Potential earnings depend on accumulated work experience $\kappa$: \[ \log(W) = \phi_{0} + \phi_{1}\kappa,\qquad \kappa_{t+1} = \kappa_{t} + H_{j_t}. \] So working today raises wages tomorrow. This gives the model a second dynamic trade-off: participating in welfare instead of working forgoes human capital.

Benefits and the time limit. Let $\omega$ be the number of periods of prior program use, which evolves as $\omega_{t+1}=\omega_{t}+P_{j_t}$. A family that participates receives a benefit that is reduced by a fraction $\tau$ of earnings (the benefit reduction rate): \[ B(W,H) = \max\{0,\ b - \tau HW\}. \] Net income from choice $j$ is $Y_{j}(W) = H_{j}W + P_{j}B(W,H_{j})$. Under a lifetime limit of $\Omega$ periods, participation is only available if $\omega<\Omega$. Let $\mathcal{J}(\omega)$ be the set of available choices: all four choices if $\omega<\Omega$, and only $j\in\{1,2\}$ otherwise.

Payoffs. The flow payoff from choice $j$ is: \[ u_{j}(\kappa) + \varepsilon_{j} = \log\left(\gamma + Y_{j}(W(\kappa))\right) - \alpha P_{j} - \varphi H_{j} + \varepsilon_{j} \] where $\gamma$ represents income from other sources (it also ensures that utility is well-defined with zero earnings and benefits), $\alpha$ is the disutility of participation (stigma, hassle, and transaction costs, as in Moffitt (1983)), $\varphi$ is the disutility of work, and $\varepsilon_{j}$ is iid Type I extreme value with scale $\sigma$.

State and timing. The state is $x_{t} = (\omega_{t},\kappa_{t})$, and all families start with $\omega_{1}=\kappa_{1}=0$. Families discount the future at rate $\beta$, and the value of any state after period $T$ is zero.

Measurement. The econometrician observes choices and states for every family in every period. Wages are only observed for those who work, and with error: $\log(W^{o}) = \log(W) + \xi$ where $\xi\sim\mathcal{N}(0,\sigma^2_{\xi})$ is independent of everything else.

Notice that this model satisfies Rust’s assumptions (Definition 16.1). The state transitions are deterministic given the choice, and so the transition “matrices” $f_{j}(x'|x)$ require no estimation.

19.1.1 Solving the Model

Since the horizon is finite, the conditional value functions are indexed by time and we can solve the model by backward induction. For $t=T,T-1,\ldots,1$: \[ v_{jt}(\omega,\kappa) = u_{j}(\kappa) + \beta V_{t+1}(\omega+P_{j},\kappa+H_{j}),\qquad V_{t}(\omega,\kappa) = \sigma\gamma_{e} + \sigma\log\left(\sum_{j\in\mathcal{J}(\omega)}\exp(v_{jt}(\omega,\kappa)/\sigma)\right) \] with $V_{T+1}=0$, where $\gamma_{e}$ is Euler’s constant. The choice probabilities are: \[ p_{jt}(\omega,\kappa) = \frac{\exp(v_{jt}(\omega,\kappa)/\sigma)}{\sum_{k\in\mathcal{J}(\omega)}\exp(v_{kt}(\omega,\kappa)/\sigma)},\qquad j\in\mathcal{J}(\omega). \]

19.1.2 How Time Limits Change Behavior

Before computing anything, let’s see what the model says about anticipation. Consider the difference in conditional values between participating and not participating (holding the work decision fixed): \[ v_{3t}(\omega,\kappa) - v_{1t}(\omega,\kappa) = \underbrace{u_{3}(\kappa) - u_{1}(\kappa)}_{\text{static gain}} - \beta\underbrace{\left[V_{t+1}(\omega,\kappa) - V_{t+1}(\omega+1,\kappa)\right]}_{\text{value of a period of eligibility}}. \] Without a time limit, the second term is zero: participation today has no effect on the future. With a time limit, it is non-negative, and so time limits reduce participation at every state where the term is positive, not just at states where the limit binds. This is the banking prediction.

When is the value of a period of eligibility zero? If, after participating today, the family has more periods of eligibility left ($\Omega-\omega-1$) than it has periods left in which to use them ($T-t$), then the limit can never bind and one more period of use has no cost. So the anticipation effect is zero whenever $T-t\leq\Omega-\omega-1$, and is otherwise positive. Families with a long remaining horizon (young children) or with little remaining eligibility have the most reason to bank. This is the logic behind the empirical test of Grogger and Michalopoulos (2003).

19.2 Solving and Simulating the Model

Example: Solving the Model by Backward Induction

Example 19.1 Let’s start with some parameters. Income is measured in dollars per week. A family with no experience can earn about $220 per week, and wages grow by 5% with each year of experience. The maximum benefit is $200 per week with a benefit reduction rate of 50%. We set $T=20$ and a lifetime limit of $\Omega=5$ years, mirroring the 60-month federal limit.

pars = (;
    T = 20,          #<- number of periods a family is potentially eligible
    Ω = 5,           #<- lifetime limit on program use
    b = 200.,        #<- maximum weekly benefit
    τ = 0.5,         #<- benefit reduction rate on earnings
    ϕ = (5.4,0.05),  #<- log wage equation: log(W) = ϕ[1] + ϕ[2]κ
    γ = 50.,         #<- weekly income from other sources
    α = 0.9,         #<- disutility of program participation
    φ = 1.2,         #<- disutility of work
    σ = 0.5,         #<- scale of the taste shocks
    β = 0.95,        #<- discount factor
    σ_ξ = 0.2)       #<- std dev of measurement error in log wages

(T = 20, Ω = 5, b = 200.0, τ = 0.5, ϕ = (5.4, 0.05), γ = 50.0, α = 0.9, φ = 1.2, σ = 0.5, β = 0.95, σ_ξ = 0.2)

Here are the payoff primitives. We store choices as integers $j\in\{1,2,3,4\}$ and look up the work and participation decisions with H_j and P_j.

const H_j = (0,1,0,1)
const P_j = (0,0,1,1)

wage(κ,ϕ) = exp(ϕ[1] + ϕ[2]*κ)
benefit(W,H,b,τ) = max(0., b - τ*H*W)
net_income(W,H,P,b,τ) = H*W + P*benefit(W,H,b,τ)
flow_utility(W,H,P,pars) = log(pars.γ + net_income(W,H,P,pars.b,pars.τ)) - pars.α*P - pars.φ*H
available(P,ω,Ω) = P==0 || ω<Ω #<- program participation requires remaining eligibility

available (generic function with 1 method)

Now the backward induction. We store log choice probabilities in an array indexed by $(j,\omega+1,\kappa+1,t)$. Two details are worth noting. First, in period $t$ a family can have at most $t-1$ periods of experience or program use, so we only solve at reachable states. Second, we drop the constant $\sigma\gamma_{e}$ from the value function. This shifts every value by the same amount and has no effect on choices.

# fill in log choice probabilities and the value at state (ω,κ) in period t
function iterate!(logP,V,v,pars,ω,κ,t)
    (;β,ϕ,Ω,σ,T) = pars
    W = wage(κ,ϕ)
    nJ = ω<Ω ? 4 : 2 #<- choices 3 and 4 (participation) unavailable once the limit is reached
    for j in 1:nJ
        H,P = H_j[j],P_j[j]
        κ′ = min(κ + H, T-1)
        ω′ = min(ω + P, Ω)
        v[j] = flow_utility(W,H,P,pars) + β*V[ω′+1,κ′+1,t+1]
    end
    vmax = maximum(v[1:nJ])
    logsum = vmax + σ*log(sum(exp((v[j] - vmax)/σ) for j in 1:nJ))
    for j in 1:4
        logP[j,ω+1,κ+1,t] = j<=nJ ? (v[j] - logsum)/σ : -Inf
    end
    V[ω+1,κ+1,t] = logsum
end

# solve by backward induction. Returns log choice probabilities and values
function solve(pars)
    (;T,Ω,α,φ,σ,γ) = pars
    R = promote_type(typeof(α),typeof(φ),typeof(σ),typeof(γ))
    V = zeros(R,Ω+1,T,T+1) #<- values in period T+1 are zero
    logP = zeros(R,4,Ω+1,T,T)
    v = zeros(R,4)
    for t in reverse(1:T), κ in 0:t-1, ω in 0:min(t-1,Ω) #<- only reachable states
        iterate!(logP,V,v,pars,ω,κ,t)
    end
    return logP,V
end

logP,V = solve(pars);

Notice that once the family has reached the limit, we only compute conditional values for the available choices rather than setting the values of unavailable choices to $-\infty$. This is not just cosmetic: we will want to differentiate through this code with automatic differentiation, and arithmetic with infinite values tends to produce NaN derivatives.

To see anticipation at work, let’s solve a version of the model with no time limit. Setting $\Omega=T$ does the trick, since no family can use up $T$ periods of eligibility before period $T$ is over. We then compare the probability of participating for a family with no prior use and no experience in each period.

using Plots
pars_nolimit = (;pars..., Ω = pars.T)
logP_nolimit,_ = solve(pars_nolimit)

prob_participate(logP,ω,κ,t) = exp(logP[3,ω+1,κ+1,t]) + exp(logP[4,ω+1,κ+1,t])
plot(1:pars.T,[prob_participate(logP_nolimit,0,0,t) for t in 1:pars.T],label="No time limit",marker=:circle)
plot!(1:pars.T,[prob_participate(logP,0,0,t) for t in 1:pars.T],label="Time limit (Ω=5)",marker=:circle)
vline!([pars.T - pars.Ω + 1],linestyle=:dash,color=:gray,label="T - Ω + 1")
xlabel!("Period (t)"); ylabel!("P(participate | ω=0, κ=0)")

As predicted, the time limit reduces participation even for families who have never used welfare, and the effect is largest early on, when the remaining horizon is longest. From period $T-\Omega+1=16$ onward, a family with $\omega=0$ can never exhaust its eligibility and the two models coincide.

Banking also depends on how much eligibility remains. Let’s look at a family in period 5 with one year of experience and different amounts of prior use:

[(ω = ω, limit = round(prob_participate(logP,ω,1,5),digits=3), no_limit = round(prob_participate(logP_nolimit,ω,1,5),digits=3)) for ω in 0:3]

4-element Vector{@NamedTuple{ω::Int64, limit::Float64, no_limit::Float64}}:
 (ω = 0, limit = 0.365, no_limit = 0.496)
 (ω = 1, limit = 0.321, no_limit = 0.496)
 (ω = 2, limit = 0.269, no_limit = 0.496)
 (ω = 3, limit = 0.205, no_limit = 0.496)

Without a limit, prior use has no effect on behavior. With a limit, families who have used more of their eligibility are less likely to participate, even though $\omega$ does not enter flow payoffs.

Example: Simulating Life-Cycle Profiles

Example 19.2 To simulate data, we draw a choice for each family in each period from the CCPs, update the states, and draw observed wages for workers. The function below takes the log choice probabilities as an argument and enforces eligibility using the time limit in pars. If logP allows participation at a state where the family is ineligible, we remove those choices and renormalize. This seems odd now, but it will be useful when we decompose the effect of the time limit below. We pre-draw all of the random numbers so that calling the function with the same seed delivers the same draws.

using Random, Statistics
function simulate(logP,pars,N; seed = 1234)
    (;T,Ω,ϕ,σ_ξ) = pars
    rng = MersenneTwister(seed)
    u = rand(rng,N,T) #<- draws for choices
    ξ = σ_ξ .* randn(rng,N,T) #<- measurement error in wages
    J = zeros(Int,N,T)
    ω = zeros(Int,N,T)
    κ = zeros(Int,N,T)
    logWo = fill(NaN,N,T) #<- wages only observed for workers
    p = zeros(4)
    for n in 1:N
        for t in 1:T
            for j in 1:4
                p[j] = available(P_j[j],ω[n,t],Ω) ? exp(logP[j,ω[n,t]+1,κ[n,t]+1,t]) : 0.
            end
            p ./= sum(p)
            j = min(findfirst(cumsum(p) .> u[n,t]),4)
            J[n,t] = j
            H,P = H_j[j],P_j[j]
            if H==1
                logWo[n,t] = log(wage(κ[n,t],ϕ)) + ξ[n,t]
            end
            if t<T
                κ[n,t+1] = κ[n,t] + H
                ω[n,t+1] = ω[n,t] + P
            end
        end
    end
    return (;J,ω,κ,logWo)
end

# summary statistics by period: shares working, participating, and at the limit
function profiles(data,pars)
    (;J,ω) = data
    work = vec(sum([H_j[j] for j in J]; dims=1)) ./ size(J,1)
    part = vec(sum([P_j[j] for j in J]; dims=1)) ./ size(J,1)
    at_limit = vec(sum(ω .>= pars.Ω; dims=1)) ./ size(J,1)
    return (;work,part,at_limit)
end

profiles (generic function with 1 method)

Let’s simulate a panel of 2,000 families and plot their behavior over the life-cycle.

data = simulate(logP,pars,2_000)
prof = profiles(data,pars)
plot(1:pars.T,[prof.work prof.part prof.at_limit],label=["Working" "Participating" "Exhausted limit"],marker=:circle,xlabel="Period (t)",ylabel="Fraction of families")

Employment rises over the life-cycle as families accumulate experience and wages grow, and participation falls. Some of the decline in participation is due to rising wages, some is due to families exhausting their eligibility, and some is due to families saving their eligibility for later.

Here are the overall shares of each choice:

labels = ["Neither","Work only","Welfare only","Work and welfare"]
[(choice = labels[j], share = round(mean(data.J .== j),digits=3)) for j in 1:4]

4-element Vector{@NamedTuple{choice::String, share::Float64}}:
 (choice = "Neither", share = 0.094)
 (choice = "Work only", share = 0.677)
 (choice = "Welfare only", share = 0.163)
 (choice = "Work and welfare", share = 0.066)

19.3 Estimation

The parameters can be divided into three groups:

The policy parameters $(T,\Omega,b,\tau)$ are known to the econometrician.
The wage parameters $(\phi_{0},\phi_{1})$ and $\sigma_{\xi}$ govern the evolution of earnings. Since the measurement error $\xi$ is independent of choices, $\mathbb{E}[\log W^{o}|\kappa,H=1] = \phi_{0}+\phi_{1}\kappa$. The selection problem that we encountered in the generalized Roy model does not arise here because the only unobservables that drive choices ($\varepsilon$) are independent of wages. Hence we can estimate the wage equation by OLS on the sample of workers.
The preference parameters $(\alpha,\varphi,\sigma,\gamma)$ are estimated by maximizing the likelihood of choices, given $\hat{\phi}$. We will fix $\beta$ at its true value.

This is an instance of the multi-step approach described in the framework chapter: we estimate objects that govern the evolution of the state outside the model, and then plug them in.

You might wonder why we can estimate $\sigma$ here, when in the entry model we normalized it to one. The reason is that income enters payoffs with a known coefficient (through $\log(\gamma+Y)$), and income varies across choices and states in a way that we observe. This pins down the scale of utility, and hence $\sigma$. Similarly, $\gamma$ is identified from the curvature of utility in income. Both of these are examples of identification by functional form. If we instead specified $u_{j}$ as a linear function of income with an unknown coefficient, we would need to normalize the scale.

Example: Estimating the Model by Nested Fixed Point

Example 19.3 First, the wage equation.

# OLS estimates of the wage equation using observed wages of workers
function estimate_wages(data)
    (;κ,logWo) = data
    work = .!isnan.(logWo)
    X = [ones(sum(work)) κ[work]]
    return X \ logWo[work]
end
ϕ̂ = estimate_wages(data)

2-element Vector{Float64}:
 5.397759755666271
 0.050277608675331265

Next, the log-likelihood. We estimate $x = (\alpha,\varphi,\log\sigma,\log\gamma)$, which keeps $\sigma$ and $\gamma$ positive.

function log_likelihood(logP,data)
    (;J,ω,κ) = data
    ll = zero(eltype(logP))
    N,T = size(J)
    for n in 1:N, t in 1:T
        ll += logP[J[n,t],ω[n,t]+1,κ[n,t]+1,t]
    end
    return ll
end

# preference parameters x = (α, φ, log σ, log γ), other parameters fixed at pars
function update_pars(x,pars)
    return (;pars..., α = x[1], φ = x[2], σ = exp(x[3]), γ = exp(x[4]))
end

function log_likelihood(x::AbstractVector,data,pars)
    logP,_ = solve(update_pars(x,pars))
    return log_likelihood(logP,data)
end

log_likelihood (generic function with 2 methods)

We plug in the wage estimates and maximize using Newton’s method with automatic differentiation through the backward induction.

using Optim, ForwardDiff, LinearAlgebra
pars_est = (;pars..., ϕ = Tuple(ϕ̂))
obj(x) = -log_likelihood(x,data,pars_est)
x0 = [0.,0.,0.,log(100.)]
res = optimize(obj,x0,Newton(),autodiff=:forward)
x̂ = res.minimizer
H = ForwardDiff.hessian(obj,x̂)
se = sqrt.(diag(inv(H)))
x_true = [pars.α,pars.φ,log(pars.σ),log(pars.γ)]
for (i,name) in enumerate(["α","φ","log σ","log γ"])
    println("$name: estimate = $(round(x̂[i],digits=3)), se = $(round(se[i],digits=3)), truth = $(round(x_true[i],digits=3))")
end

α: estimate = 0.841, se = 0.055, truth = 0.9
φ: estimate = 1.143, se = 0.049, truth = 1.2
log σ: estimate = -0.753, se = 0.074, truth = -0.693
log γ: estimate = 4.051, se = 0.134, truth = 3.912

The estimates are all within about one standard error of the truth. As in the entry model, these standard errors do not account for the first-stage estimation of $\phi$. Here’s how long estimation takes:

@time optimize(obj,x0,Newton(),autodiff=:forward);

  0.019279 seconds (79.02 k allocations: 43.565 MiB, 34.36% gc time)

Backward induction over a few thousand states is cheap, so estimation is quick.

19.4 Counterfactuals: Mechanical and Behavioral Effects

What is the effect of the time limit? To answer this question, let’s compare three scenarios:

Baseline: there is no time limit, and families behave according to the CCPs of the model without a limit, $p^{\infty}$.
Mechanical: families continue to behave according to $p^{\infty}$, but those who reach $\Omega$ are no longer able to participate. They choose between the remaining options with probabilities proportional to $p^{\infty}$. This scenario describes a world in which families do not anticipate the limit until it binds.
Total: families behave according to the CCPs of the model with the limit, $p^{\Omega}$.

The difference between scenarios 2 and 1 is the mechanical effect of the time limit, and the difference between scenarios 3 and 2 is the behavioral effect. The behavioral effect is a consequence of forward-looking behavior, and it can only be computed with a model.

Example: Decomposing the Effect of a Time Limit

Example 19.4 Since simulate enforces eligibility using pars and renormalizes the CCPs, we can simulate the mechanical scenario by passing the no-limit CCPs with the time-limit parameters. We use the same seed for each scenario, so the comparisons are made using common random numbers.

N = 5_000
baseline = profiles(simulate(logP_nolimit,pars_nolimit,N),pars_nolimit)
mechanical = profiles(simulate(logP_nolimit,pars,N),pars)
total = profiles(simulate(logP,pars,N),pars)

pl1 = plot(1:pars.T,[baseline.part mechanical.part total.part],label=["Baseline" "Mechanical" "Total"],title="Participation",xlabel="Period (t)",marker=:circle)
pl2 = plot(1:pars.T,[baseline.work mechanical.work total.work],label=["Baseline" "Mechanical" "Total"],title="Employment",xlabel="Period (t)",marker=:circle,legend=:bottomright)
plot(pl1,pl2,size=(800,350))

The two channels operate at very different times. Early on, no family has exhausted its eligibility, so the mechanical effect is zero and the entire reduction in participation is behavioral. Later in the life-cycle, the mechanical effect dominates. In fact, toward the end of the horizon, participation is higher under the total scenario than under the mechanical scenario. Families who banked their eligibility early have it available to use later.

Summing over the life-cycle gives the expected number of years on welfare and in work in each scenario:

for (name,s) in zip(["Baseline","Mechanical","Total"],[baseline,mechanical,total])
    println("$name: years on welfare = $(round(sum(s.part),digits=2)), years worked = $(round(sum(s.work),digits=2))")
end

Baseline: years on welfare = 8.85, years worked = 11.65
Mechanical: years on welfare = 4.95, years worked = 14.19
Total: years on welfare = 4.58, years worked = 14.84

Over the full life-cycle, most of the reduction in welfare use is mechanical, while the behavioral response accounts for a larger share of the increase in employment.

Example: Varying the Time Limit

Example 19.5 Policymakers chose a 60-month limit, but states were free to set shorter ones. Let’s see how welfare use and employment vary with $\Omega$, as well as the share of the total effect (relative to no limit) that is behavioral.

function decompose(pars,N)
    pars_nolimit = (;pars..., Ω = pars.T)
    logP_nolimit,_ = solve(pars_nolimit)
    logP,_ = solve(pars)
    base = profiles(simulate(logP_nolimit,pars_nolimit,N),pars_nolimit)
    mech = profiles(simulate(logP_nolimit,pars,N),pars)
    tot = profiles(simulate(logP,pars,N),pars)
    years(s) = (welfare = sum(s.part), work = sum(s.work))
    return (;base = years(base), mech = years(mech), tot = years(tot))
end

for Ω in [2,5,10]
    d = decompose((;pars...,Ω),N)
    Δtot = d.tot.welfare - d.base.welfare
    Δbeh = d.tot.welfare - d.mech.welfare
    println("Ω = $Ω: years on welfare = $(round(d.tot.welfare,digits=2)), years worked = $(round(d.tot.work,digits=2)), behavioral share of reduction in welfare = $(round(Δbeh/Δtot,digits=2))")
end

Ω = 2: years on welfare = 1.9, years worked = 16.74, behavioral share of reduction in welfare = 0.01
Ω = 5: years on welfare = 4.58, years worked = 14.84, behavioral share of reduction in welfare = 0.09
Ω = 10: years on welfare = 7.9, years worked = 12.37, behavioral share of reduction in welfare = 0.45

A tighter limit reduces welfare use and increases employment, as expected. More interestingly, the share of the reduction in welfare use that is behavioral rises with the length of the limit. A very short limit is quickly exhausted by most families, so its effects are mostly mechanical. A long limit rarely binds, but the possibility that it might bind in the future is enough to change behavior today.

Discussion: What Would a Before-After Comparison Tell Us?

Suppose that a researcher had data on a cohort of families before and after the introduction of a time limit, and computed the change in participation in the first two years after the reform.

Which component of the total effect, mechanical or behavioral, would this comparison capture? What would a researcher conclude about the long-run effect of the reform if they extrapolated from it?
Grogger and Michalopoulos (2003) compare families with young and old children. Using the model, explain why this comparison isolates the behavioral effect. What assumptions does it require?
In practice, TANF also changed many other features of the welfare system at the same time (work requirements, benefit reduction rates, sanctions), and the economy was booming in the late 1990s. How would a researcher use a structural model to separate these influences? What would they need to assume?

19.5 Identification

The framework chapter showed that the payoffs of dynamic discrete choice models are not identified without some restrictions (Theorem 16.1). In this model, we have imposed a lot of structure: payoffs depend on the state only through income, which depends on the state only through observed wages and the known benefit formula. Every source of variation in income across states and choices is known to the econometrician. This structure is what allows us to estimate the scale $\sigma$ and the income parameter $\gamma$.

The time limit itself offers an interesting source of identification. Cumulative use $\omega$ does not enter flow payoffs at all (until the limit binds). Hence, conditional on experience and time, differences in choices across values of $\omega$ are driven entirely by differences in continuation values. Recall from the framework chapter that this is exactly the kind of exclusion restriction that can help to identify the discount factor. Similarly, variation in the time limit across states or over time would shift continuation values while leaving flow payoffs unchanged.

Discussion: Restrictions and Their Consequences

Suppose that we observe families who never participate in welfare, perhaps because they live in a state where they are ineligible. How would this change what we can learn about $\alpha$?
Our model assumes that there is no persistent unobserved heterogeneity. If families differ in their stigma $\alpha$, those with low stigma will participate more and exhaust their eligibility sooner. How would this affect the relationship between $\omega$ and participation in the data? Would our estimate of the behavioral effect be biased up or down?
Families in this model cannot save. How might the ability to save interact with a time limit?

19.6 Further Reading

Grogger and Michalopoulos (2003) develop the theory of time limits and the banking prediction, and test it using experimental data. Grogger (2003) estimates the effects of time limits and other policy changes in the 1990s using cross-state variation. Swann (2005) estimates a dynamic model of welfare participation, labor supply, and marriage to evaluate time limits and other reforms. Fang and Keane (2004) estimate a rich model of single mothers’ behavior to assess the effects of the various features of the 1996 reform, and Chan (2013) estimates a dynamic model of welfare reform that pays close attention to how time limits and work requirements interact. Keane and Wolpin (2010) provide a broad model of women’s life-cycle decisions in which the welfare system plays a central role.

19.7 Exercises

Exercise

Exercise 19.1 Several states adopted policies that “stop the clock” for working recipients: a period in which a family both works and participates does not count toward the time limit. Alternatively, some states reduced the benefit reduction rate $\tau$ (often called an “earnings disregard”) to encourage recipients to work.

Modify the code from Example 19.1 so that $\omega_{t+1} = \omega_{t} + P_{j}(1-H_{j})$. Solve the model and decompose the effects of the time limit into mechanical and behavioral components as in Example 19.4.
Compare the effects of the time limit on welfare use and employment with and without the stop-the-clock policy.
Now consider the original model (no stopping the clock) and reduce the benefit reduction rate to $\tau=0.25$. Compare the effect of this change on the share of families who combine work and welfare with and without a time limit. Use the model to explain why the two policies interact.

Exercise

Exercise 19.2 In this exercise you will investigate how well a reduced-form research design recovers the behavioral effect of a time limit.

Suppose that at the time of a reform, the population of families is evenly distributed across periods $t\in\{1,\ldots,T\}$, and that they have been behaving according to the model with no time limit. When the reform is introduced, every family’s clock starts at zero ($\omega=0$) regardless of past use, and families behave according to the model with a time limit from then on.

Simulate the population of families in the year before the reform (you will need to simulate their histories to get the distribution of experience in each period). Then simulate the year after the reform.
Classify families as “long horizon” if $T-t\geq\Omega$ and “short horizon” otherwise, where $t$ is their period in the year of the reform. Calculate the difference-in-differences estimate of the effect of the reform on participation, comparing long and short horizon families.
Using the model, calculate the true behavioral effect of the reform on long horizon families in the first year after the reform. Does the difference-in-differences estimate recover it? Why or why not?
Suppose that the disutility of work $\varphi$ declines with $t$ (because children get older). Does this change your answer to part 3? What about if wages also grew because of a booming economy in the year of the reform?

Exercise

Exercise 19.3 Suppose that families are of two types with different stigma costs, $\alpha\in\{0.4,1.4\}$, with equal probability. Each family’s type is fixed over time and is unknown to the econometrician.

Simulate a panel of 2,000 families from this model and estimate the model without heterogeneity using the code from Example 19.3.
Compare the relationship between prior use $\omega$ and participation in the simulated data with the relationship implied by your estimates.
Use your estimates to decompose the effect of the time limit into mechanical and behavioral components, and compare this to the true decomposition. In what direction is the behavioral effect biased? Explain.
We will see how to estimate models with unobserved types in the chapter on finite mixtures. Come back to this exercise once you have read it.