include("../scripts/flfp_model.jl")18 Female Labor Force Participation
The dramatic rise in the labor force participation of married women is one of the defining features of the labor market in the second half of the twentieth century. Understanding this behavior has occupied labor economists for decades, and for good reason: the participation decisions of women respond to wages, taxes, transfers, child care costs, and the earnings of their spouses, so they sit at the center of many important policy debates.
A static model of labor supply treats each year’s participation decision in isolation: a woman works if the wage she can earn exceeds her reservation wage. But there are good reasons to think that dynamics matter. Wages grow with experience, so time spent out of the labor force (often to care for young children) has a lasting cost in the form of lower future wages. The large and persistent decline in women’s earnings after the birth of a first child (the “child penalty” documented by Kleven, Landais, and Søgaard (2019)) is partly a consequence of this. And if working today is partly an investment in future wages, then the response of labor supply to a change in wages will depend on whether that change is temporary or permanent, anticipated or unanticipated, and on how much of the working life remains to reap the returns (Imai and Keane 2004).
In this chapter we use the framework from the framework chapter to build a simple version of the model of Eckstein and Wolpin (1989), which was among the first to estimate a dynamic model of female labor force participation with endogenous work experience. We will:
- Write down a finite-horizon model and solve it by backward induction.
- Simulate a panel of women and estimate the model in two steps: first the wage equation, and then preferences by NFXP.
- Show that, in this model, the discount factor can be estimated.
- Use the model to evaluate wage subsidies, and show what goes wrong if we use a static model to answer the same questions.
18.1 The Model
Consider a married woman who makes a participation decision \(d_{t}\in\{0,1\}\) in each year \(t=1,\ldots,T\) of her working life. We will think of \(t=1\) as age 25 and set \(T=30\). The state in period \(t\) consists of:
- Her accumulated work experience, \(h_{t}\), which evolves deterministically: \(h_{t+1} = h_{t} + d_{t}\), with \(h_{1}=0\).
- Her husband’s income, \(y_{t}\), which follows an exogenous Markov process. We will discretize an AR(1) process for \(\log(y)\) on a grid using the same method as for the entry model.
- An indicator \(k_{t}\) that there is a young child in the household. The probability of a birth, \(b(t)\), declines with age, and a young child remains young in the next period with probability \(\varsigma\).
If she works, she earns a wage that depends on her experience:
\[ \log(w(h)) = \gamma_{0} + \gamma_{1}h - \gamma_{2}h^2. \]
Flow payoffs depend on household income and, if she does not work, the value of time at home:
\[ u_{1}(h,y,k) = \log(y + w(h)),\qquad u_{0}(h,y,k) = \log(y) + \alpha_{0} + \alpha_{1}k. \]
So \(\alpha_{0}\) is the value of time out of the labor force and \(\alpha_{1}\) is the additional value of time at home when there is a young child. Each choice is also subject to a payoff shock \(\varepsilon_{jt}\) that is iid Type I extreme value with scale \(\sigma\), and the woman discounts the future at rate \(\beta\). After period \(T\) there is no more decision to make, and we set \(V_{T+1}=0\).
18.1.1 What We Assume About Wages
There is one more ingredient. The econometrician observes wages only for women who work, and observes them with error:
\[ \log(W^{o}_{t}) = \log(w(h_{t})) + \xi_{t},\qquad \xi_{t}\sim\mathcal{N}(0,\sigma^2_{\xi}). \]
This specification is doing a lot of quiet work. Because the woman’s decision does not depend on \(\xi_{t}\), the sample of working women is not selected on the wage error. Hence we can estimate \((\gamma_{0},\gamma_{1},\gamma_{2})\) consistently by running OLS of observed log wages on experience in the sample of workers. Experience is endogenous in the sense that it reflects past choices, but under our assumptions those choices depend only on observed states and on payoff shocks that are independent of \(\xi\).
This is a strong assumption. In the model of Eckstein and Wolpin (1989), as in Keane and Wolpin (1997), a woman draws a wage offer before deciding whether to work, and the transitory component of that offer affects her decision. Women who work are then those who drew good offers, and OLS on the sample of workers is biased: the classic selection problem of Heckman (1979). In that case the wage shock is a payoff-relevant unobservable that enters non-additively, the logit formula for choice probabilities no longer applies, and we must integrate over the wage shock to compute the likelihood of each choice (and the joint likelihood of choices and observed wages). Keeping the wage shock out of the decision lets us stay within Definition 16.1 and estimate the model in two simple steps. You will explore what happens when this assumption fails in Exercise 18.1.
18.1.2 Normalizations and Identification
Before solving the model, let’s revisit Theorem 16.1. We have not normalized \(u_{0}=0\). Instead we have assumed that both payoffs depend on household income in a known way, through \(\log(\cdot)\), with a coefficient of one. This assumption pins down the scale of utility, so that the scale of the shocks, \(\sigma\), can be estimated. It also restricts how \(u_{0}\) depends on the state: up to the constant \(\alpha_{0}+\alpha_{1}k\), the payoff from not working is a known function of the data. This is the kind of restriction on the reference payoff that Theorem 16.1 requires.
Notice also that wages are pinned down entirely by the first step. Once we know \(w(h)\), the pecuniary return to experience is known, and the remaining parameters \((\alpha_{0},\alpha_{1},\sigma)\) are identified from how participation varies with the wage, the husband’s income, and the presence of children. In richer models, people often allow experience to affect the non-pecuniary value of work as well (for example through habit formation or a cost of re-entering the labor force). As we saw in the framework chapter, separating these channels requires care.
18.2 Solving the Model
Since the horizon is finite, we solve the model by backward induction. Starting from \(V_{T+1}=0\), in each period \(t\) we calculate the conditional values:
\[ v_{jt}(h,y,k) = u_{j}(h,y,k) + \beta\sum_{y',k'}V_{t+1}(h + j,y',k')f_{y}(y'|y)f_{kt}(k'|k) \]
and then:
\[ V_{t}(h,y,k) = \sigma\gamma + \sigma\log\left(\exp(v_{0t}/\sigma) + \exp(v_{1t}/\sigma)\right),\qquad p_{1t}(h,y,k) = \frac{\exp(v_{1t}/\sigma)}{\exp(v_{0t}/\sigma)+\exp(v_{1t}/\sigma)}. \]
In period \(t\) a woman can have at most \(t-1\) years of experience, so we only need to solve the model for \(h\in\{0,\ldots,t-1\}\).
Example: Solving the Model
Example 18.1 The code for this model is collected in a script. The function flfp_environment collects everything about the environment other than preferences: the horizon, the grid and transition matrix for husband’s income, the wage parameters, and the fertility process. Here is the function that solves the model:
function solve_flfp(θ,env,β)
(;T,Ky,ygrid,Fy) = env
(;σ) = θ
R = promote_type(typeof(θ.α0),typeof(θ.α1),typeof(σ),typeof(β))
V = zeros(R,T+1,Ky,2,T+1)
logp1 = zeros(R,T,Ky,2,T)
logp0 = zeros(R,T,Ky,2,T)
for t in T:-1:1
Fk = child_transition(t,env)
for k in 0:1, iy in 1:Ky, h in 0:t-1
# expected continuation values given next period's experience
EV0 = zero(R); EV1 = zero(R)
for k′ in 0:1, iy′ in 1:Ky
f = Fy[iy,iy′] * Fk[k+1,k′+1]
EV0 += f * V[h+1,iy′,k′+1,t+1]
EV1 += f * V[h+2,iy′,k′+1,t+1]
end
y = ygrid[iy]
v0 = u0(h,y,k,t,θ,env) + β*EV0
v1 = u1(h,y,k,t,θ,env) + β*EV1
vmax = max(v0,v1)
logsum = vmax + σ*log(exp((v0-vmax)/σ) + exp((v1-vmax)/σ))
V[h+1,iy,k+1,t] = σ*γₑ + logsum
logp1[h+1,iy,k+1,t] = (v1 - logsum)/σ
logp0[h+1,iy,k+1,t] = (v0 - logsum)/σ
end
end
return (;logp1,logp0,V)
endA few things to note. First, the arrays are indexed as [h+1,iy,k+1,t], with Julia’s 1-based indexing requiring the +1s. Second, we store log choice probabilities, which we will need for the likelihood. Third, we use promote_type to make sure the arrays can hold dual numbers when we differentiate the solution with ForwardDiff. Finally, the payoff functions u0 and u1 take the period \(t\) as an argument. This allows us to introduce time-varying wage subsidies later on.
Let’s solve the model at our default parameters. Wages and incomes are measured in tens of thousands of dollars per year: a woman with no experience earns about $15,000 and the median husband earns about $50,000.
using Plots, Statistics
env = flfp_environment()
β = 0.95
θ = (;α0 = 0.3, α1 = 0.3, σ = 0.25)
sol = solve_flfp(θ,env,β)
age = 24 .+ (1:env.T)
iy = 3 #<- median husband's income
pl = plot(xlabel="Age",ylabel="Pr(work)",legend=:outerright,size=(750,400))
for h in [0,5,10]
t = h+1:env.T
plot!(pl,age[t],exp.(sol.logp1[h+1,iy,1,t]),label="h = $h, no child")
plot!(pl,age[t],exp.(sol.logp1[h+1,iy,2,t]),label="h = $h, young child",linestyle=:dash,color=pl.series_list[end][:linecolor])
end
pl
Participation is increasing in experience (since wages are), and lower when there is a young child. Notice what happens late in life: holding experience fixed, the probability of working falls as the end of the working life approaches. This is the investment motive at work. Early in life, a year of work raises wages for many years to come. Near the end, there is little future left in which to collect the return.
18.3 Simulating Data
Simulating data from the model is straightforward. Each woman begins at \(t=1\) with no experience, a husband’s income drawn from the stationary distribution, and a young child with probability 0.3. We then draw choices from the CCPs, update experience, and draw the exogenous states.
Example: Simulating a Panel of Women
Example 18.2 The function simulate_flfp returns \(T\times N\) arrays of experience (H), the index of husband’s income (Y), the child indicator (K), choices (D), and observed log wages (logW, which is NaN when the woman does not work). Let’s simulate \(N=2,000\) women observed over the full 30 years.
data = simulate_flfp(sol.logp1,env,2000; seed = 1);The script also includes a function life_cycle_profile that calculates participation rates and average experience at each age exactly, by iterating the distribution of states forward using the choice probabilities and transitions. This will be useful for counterfactuals, since it avoids simulation noise. Let’s compare it to the simulated data.
prof = life_cycle_profile(sol.logp1,env)
plot(age,mean(data.D,dims=2),label="Simulated",xlabel="Age",ylabel="Participation rate")
plot!(age,prof.part,label="Model (exact)")
Participation rises over the life-cycle from about 50% to 70%, as women accumulate experience and their children grow up. Women with a young child participate much less:
[mean(data.D[data.K.==0]) mean(data.D[data.K.==1])]1×2 Matrix{Float64}:
0.706956 0.38795718.4 Estimation
We estimate the model in two steps. In the first step, we estimate the wage equation by OLS using the sample of workers, which is valid under our assumption on the wage error. We also take the transition processes for husband’s income and children as known, although these could be estimated directly in the same way as \(\mathbf{F}_{x}\) in the entry model. In the second step, we estimate \(\theta=(\alpha_{0},\alpha_{1},\sigma)\) by maximizing the partial likelihood of choices, re-solving the model at each trial value of \(\theta\). Since \(\sigma>0\) we estimate \(\log(\sigma)\).
18.4.1 Estimating the Discount Factor
Recall from the framework chapter that identifying the discount factor requires something that shifts the continuation values of choices without affecting flow payoffs. In this model age plays that role: flow payoffs do not depend on \(t\), but the return to accumulating experience falls as the end of the working life approaches. Our parametric assumptions also help. Since the pecuniary return to experience is known from the wage equation, the value that women place on that return (relative to the flow payoff today) is informative about \(\beta\). Let’s try it.
18.5 Counterfactuals: Temporary and Permanent Wage Subsidies
Now let’s use the model to evaluate a policy. Suppose that the government offers an earnings subsidy that tops up a woman’s wage by 25%. We will consider three versions:
- An early, temporary subsidy available only in the first five years (\(t\leq 5\), ages 25 to 29).
- A late, temporary subsidy available only in years 21 to 25 (ages 45 to 49). We assume that women know about this subsidy from the beginning of their working lives.
- A permanent subsidy available in every year.
To see why a dynamic model matters, we will compare the predictions of our model with those of a static model. Suppose that a researcher estimated the model assuming that women are myopic (\(\beta=0\)). This model still has experience affecting wages, but women ignore this when deciding whether to work. How different are its predictions?
Example: The Effects of Wage Subsidies
Example 18.5 First, let’s estimate the static model using the same data:
x_static = optimize(x->-log_likelihood(x,data,env_hat,0.),x0,Newton(),autodiff=:forward).minimizer
θ_static = (;α0 = x_static[1], α1 = x_static[2], σ = exp(x_static[3]))(α0 = 0.17598337938209058, α1 = 0.33101203291450926, σ = 0.2898099557389916)Since a myopic woman places no value on the experience she gains from working, the static model must rationalize the same participation rates with a lower value of home time (\(\hat{\alpha}_{0}\) is about 0.18 instead of 0.3) and noisier choices (a larger \(\hat{\sigma}\)). Next, here is a function that calculates the change in the participation profile caused by a subsidy, given parameters, the discount factor, and the wage equation:
function subsidy_effect(θ,β,γ,s)
env0 = flfp_environment(;γ)
env1 = flfp_environment(;γ,subsidy = s)
P0 = life_cycle_profile(solve_flfp(θ,env0,β).logp1,env0)
P1 = life_cycle_profile(solve_flfp(θ,env1,β).logp1,env1)
return P1.part .- P0.part
end
policies = [t -> t<=5 ? 0.25 : 0., t -> 21<=t<=25 ? 0.25 : 0., t -> 0.25]
titles = ["Early (ages 25-29)","Late (ages 45-49)","Permanent"]
plots = []
for (s,title) in zip(policies,titles)
p = plot(title=title,xlabel="Age",ylabel="Δ Pr(work)",titlefontsize=10,
legend = title==titles[2] ? :topleft : false)
plot!(p,age,subsidy_effect(θ,β,env.γ,s),label="Dynamic")
plot!(p,age,subsidy_effect(θ_static,0.,γ̂,s),label="Static")
push!(plots,p)
end
plot(plots...,layout=(1,3),size=(900,320),ylims=(-0.005,0.11),
left_margin=5Plots.mm,bottom_margin=5Plots.mm)
There are three lessons here.
First, temporary subsidies have persistent effects. Even after the early subsidy ends, participation remains higher because women who worked more during the subsidy have more experience and hence higher wages. In this example the persistence is modest (participation is about half a percentage point higher for the rest of the life-cycle), because a few extra months of experience only raise wages by a few percent. But notice that the static model also predicts persistence, since experience still affects wages. Persistence alone does not distinguish the two models.
Second, a dynamic model predicts anticipation effects. When women know that their wages will be subsidized in their late 40s, the return to accumulating experience before then rises, so they work more before the subsidy is in place. The static model, by construction, predicts no response until the subsidy arrives.
Third, the models disagree substantially about the effect of a permanent subsidy. In the dynamic model, a permanent increase in wages raises both the current return to work and the return to accumulating experience. The effect of the permanent subsidy is roughly 9 to 10 percentage points, about 50% larger than the static model’s prediction. Even though both models fit the data, the static model mistakes part of the investment motive for something else, and gets the response to a permanent policy wrong.
This last point echoes the argument of Imai and Keane (2004): if work is partly an investment in human capital, then estimates of labor supply elasticities that ignore this motive can be badly misleading.
18.6 Further Reading
Eckstein and Wolpin (1989) is the classic reference for this model. Keane and Wolpin (1997) extend this type of model to a rich model of schooling and occupational choice. Imai and Keane (2004) and Blundell et al. (2016) study the interaction between labor supply and human capital accumulation, with Blundell et al. (2016) focusing on women and on the effects of welfare reform. Adda, Dustmann, and Stevens (2017) use a dynamic model to quantify the career costs of children. Keane, Todd, and Wolpin (2011) provide an extensive review of applications of dynamic discrete choice models in labor economics.